Jak wyodrębnić odwołanie do komórki z formuł w programie Excel?

Przypuśćmy, że masz kilka długich formuł, a teraz chcesz wyodrębnić wszystkie odwołania do komórek z formuł, jak pokazano na poniższym zrzucie ekranu. Jak możesz tak szybko wyodrębnić odwołania do komórek z formuł?

Wyodrębnij odwołania do komórek z formuł za pomocą funkcji zdefiniowanej przez użytkownika

---

Wyodrębnij odwołania do komórek z formuł za pomocą funkcji zdefiniowanej przez użytkownika

Aby wyodrębnić odwołania do komórek z formuł, poniższy kod VBA może wyświadczyć ci przysługę. Wykonaj następujące czynności:

1. Przytrzymaj ALT + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

2, Kliknij wstawka > Modułi wklej następujący kod w Moduł Okno.

Kod VBA: wyodrębnij odwołania do komórek z formuł:

Function ExtractCellRefs(Rg As Range) As String
'Updateby Extendoffice
    Dim xRetList As Object
    Dim xRegEx As Object
    Dim I As Long
    Dim xRet As String
    Application.Volatile
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .Pattern = "('?[a-zA-Z0-9\s\[\]\.]{1,99})?'?!?\$?[A-Z]{1,3}\$?[0-9]{1,7}(:\$?[A-Z]{1,3}\$?[0-9]{1,7})?"
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
    End With
    Set xRetList = xRegEx.Execute(Rg.Formula)
    If xRetList.Count > 0 Then
        For I = 0 To xRetList.Count - 1
            xRet = xRet & xRetList.Item(I) & ", "
        Next
        ExtractCellRefs = Left(xRet, Len(xRet) - 2)
    Else
        ExtractCellRefs = "No Matches"
    End If
End Function

3. Po wklejeniu kodu zapisz kod i wróć do arkusza roboczego i wprowadź następującą formułę: = extractcellrefs (G2) (G2 to komórka zawierająca formułę, z której chcesz wyodrębnić odwołania do komórek) do komórki, w której chcesz uzyskać wynik, a następnie naciśnij Wchodzę klucz, wszystkie odwołania do komórek zostały wyodrębnione ze wzoru, patrz zrzut ekranu: