Przejdź do głównej zawartości

Jak uruchomić wiele makr z menu prawego przycisku myszy w programie Excel?

doc kliknij prawym przyciskiem myszy makra 5

Jeśli w skoroszycie znajduje się wiele makr VBA, należy otworzyć okno VBA, a następnie wybrać makro, gdy chcesz uruchomić kod. W tym artykule chciałbym porozmawiać o tym, jak uruchamiać makra z menu prawego przycisku myszy, aby zwiększyć wydajność pracy, jak pokazano na lewym zrzucie ekranu.

Uruchom wiele makr z menu prawego przycisku myszy z kodami VBA


Uruchom wiele makr z menu prawego przycisku myszy z kodami VBA

Aby uruchomić kody makr w skoroszycie z menu prawego przycisku myszy, poniższe kroki mogą ci pomóc, wykonaj następujące czynności:

1. Otwór Alt + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

2. Następnie kliknij dwukrotnie Ten zeszyt po lewej Projekty okienko, a następnie skopiuj i wklej poniższy kod VBA do pustego modułu.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

doc kliknij prawym przyciskiem myszy makra 1

3. Wciąż w Microsoft Visual Basic for Applications kliknij wstawka > Modułi wklej następujący kod do tego modułu.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

doc kliknij prawym przyciskiem myszy makra 2

4. Po wklejeniu kodów kliknij Tools > ReferencjeI Referencje-VBAProject zostanie wyświetlone okno dialogowe, a następnie zaznacz Rozszerzalność Microsoft Visual Basic for Applications 5.3 opcja w Dostępne referencje pole listy, zobacz zrzut ekranu:

doc kliknij prawym przyciskiem myszy makra 3

5. Następnie kliknij OK aby zamknąć okno dialogowe, należy teraz zapisać ten skoroszyt jako plik Skoroszyt Excel z włączoną obsługą makr format, patrz zrzut ekranu:

doc kliknij prawym przyciskiem myszy makra 4

6. Na koniec uruchom ponownie skoroszyt, aby zastosować kod, a teraz, po kliknięciu komórki prawym przyciskiem myszy, a Uruchom makro opcja jest wstawiana do menu prawego przycisku myszy, a wszystkie makra w skoroszycie są wymienione w podmenu jako następujący zrzut ekranu:

doc kliknij prawym przyciskiem myszy makra 5

7. Następnie możesz uruchomić kod, klikając go.


Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations