Note: The other languages of the website are Google-translated. Back to English

Łatwe liczenie unikalnych i odrębnych wartości – 7 przykładów

Zwykle w programie Excel unikatowe wartości to wartości, które pojawiają się tylko raz na liście bez żadnych duplikatów, a odrębne wartości to wszystkie różne wartości (unikalne wartości + pierwsze zduplikowane wystąpienia). Podczas pracy na dużym zbiorze danych może być konieczne policzenie liczby unikatowych i odrębnych wartości wśród duplikatów z listy komórek, jak pokazano na poniższym zrzucie ekranu. Ten samouczek wprowadzi kilka szybkich sztuczek do liczenia unikalnych i odrębnych wartości w programie Excel.

Policz unikalne wartości w programie Excel

Zliczaj odrębne wartości (unikatowe i pierwsze zduplikowane wystąpienia) w programie Excel

Pobierz przykładowy plik

Policz unikalne odrębne wartości

Policz unikalne wartości w programie Excel

W tej sekcji omówimy niektóre przykłady formuł do zliczania liczby unikalnych wartości, w tym tekstów i liczb na liście.

Policz unikalne wartości za pomocą formuł

Przypuśćmy, że mam listę nazw, która zawiera kilka zduplikowanych nazw na liście nazw. Teraz muszę uzyskać tylko liczbę unikalnych nazw (które są wypełnione żółtym kolorem), jak pokazano na poniższym zrzucie ekranu:

Aby rozwiązać ten problem, poniższa formuła tablicowa może wyświadczyć ci przysługę:

Krok 1: Wprowadź formułę

Wprowadź lub skopiuj poniższą formułę do pustej komórki, w której chcesz wyprowadzić wynik:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 Uwagi: W powyższym wzorze, A2: A12 to lista danych, którą chcesz policzyć jako unikalną.

Krok 2: Naciśnij Ctrl + Shift + Enter klucze, aby uzyskać prawidłowy wynik:

Tips:

  1. Jeśli Twoja lista komórek zawiera inne typy danych, takie jak liczby, wartości logiczne, wartości błędów itp., po zastosowaniu powyższej formuły uzyska liczbę unikalnych wartości niezależnie od typu danych.
  2. Gdy lista danych zawiera puste komórki, ta formuła wykluczy puste komórki.
  3. Do policz tylko unikalne wartości tekstowe jeśli istnieją inne typy danych, zastosuj poniższą formułę tablicową, a następnie naciśnij Ctrl + Shift + Enter klucze, aby zwrócić wynik: 
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Do liczyć tylko unikalne numery z listy komórek zawierających dane dowolnego typu, użyj następującej formuły tablicowej, a następnie naciśnij Ctrl + Shift + Enter klucze, aby zwrócić wynik: 
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Policz unikalne wartości za pomocą kilku kliknięć Kutools for Excel

Zapamiętywanie formuł, gdy będziesz musiał je zastosować następnym razem, może być bolesne. Ale jeśli masz Kutools for Excel, Z siedzibą w Policz unikalne wartości opcja Pomocnik formuł, możesz uzyskać wynik za pomocą zaledwie kilku kliknięć. Zobacz poniżej demo:

  1. Kliknij komórkę, aby wyświetlić wynik;
  2. Włącz tę funkcję, klikając Kutools > Pomocnik formuły > Pomocnik formuły > Statystyczny > Policz unikalne wartości;
  3. Wybierz listę danych > OK.
Tips:
  1. Aby zastosować tę funkcję, powinieneś pobierz i zainstaluj po pierwsze.
  2. Połączenia Pomocnik formuł funkcja gromadzi ponad 40 często używanych formuł, takich jak Wyodrębnij unikalne wartości, Wyodrębnij komórki z unikalnymi wartościami (uwzględnij pierwsze duplikaty), Policz liczbę wartości oddzielonych przecinkami, Suma na podstawie tego samego tekstu, i więcej...

Zliczaj unikalne wartości w Excel 365/2021 za pomocą formuł

Jeśli korzystasz z programu Excel 365 lub Excel 2021, dostępna jest nowa funkcja UNIQUE, która może pomóc w tworzeniu prostszych formuł do liczenia unikatowych wartości w zbiorze danych.

Na przykład, aby policzyć liczbę unikalnych nazw z zakresu A2:A12, wprowadź następującą formułę:

Krok 1: Skopiuj lub wprowadź poniższą formułę

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Uwagi: W tym wzorze A2: A12 to lista danych, dla której chcesz policzyć unikalne wartości.

Krok 2: Naciśnij Wchodzę klucz do uzyskania wyniku:

Tips:

  1. Jeśli lista danych zawiera inne typy danych, takie jak tekst, liczby, wartości logiczne, wartości błędów itp., ta formuła uzyska liczbę unikalnych wartości niezależnie od typu danych.
  2. Powyższa formuła zliczy unikalne wartości, w tym puste komórki, jeśli chcesz wykluczyć puste miejsca, zastosuj poniższą formułę i wystarczy nacisnąć Wchodzę klawisz: 
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Zliczaj odrębne wartości (unikatowe i pierwsze zduplikowane wystąpienia) w programie Excel

Aby policzyć różne wartości (wartości unikalne i pierwsze zduplikowane wystąpienia) na liście komórek, tutaj wprowadzę inne formuły, aby osiągnąć to zadanie.

Policz różne wartości za pomocą wzorów

W programie Excel możesz zastosować dowolną z poniższych formuł, aby zwrócić liczbę odrębnych wartości.

Krok 1: Wprowadź jedną z poniższych formuł

Formuła 1: Po wprowadzeniu formuły naciśnij Wchodzę klawisz.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formuła 2: Po wprowadzeniu formuły naciśnij Ctrl + Shift + Enter klawiatura.

=SUM(1/COUNTIF(A2:A12,A2:A12))
Uwagi: W tych formułach A2: A12 to lista danych, na której chcesz policzyć różne wartości.

Wynik:

Tips:

  1. Jeśli lista danych zawiera inne typy danych, takie jak liczby, wartości logiczne, wartości błędów itp., ta formuła otrzyma odrębne wartości niezależnie od typu danych.
  2. Korzystając z powyższej formuły, otrzymasz wartość błędu #DIV/0, jeśli lista danych zawiera puste komórki. Aby naprawić i zignorować puste komórki, należy zastosować jedną z poniższych formuł:
    Formuła 1: Po wprowadzeniu formuły naciśnij Wchodzę klawisz. 
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formuła 2: Po wprowadzeniu formuły naciśnij Ctrl + Shift + Enter klawiatura. 
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

  3. Do uzyskać tylko liczbę odrębnych wartości tekstowych w obrębie listy danych, zastosuj poniższą formułę tablicową i naciśnij Ctrl + Shift + Enter klucze do uzyskania wyniku: 
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Do liczyć tylko odrębne wartości liczbowe, użyj następującej formuły tablicowej i naciśnij Ctrl + Shift + Enter klucze do uzyskania wyniku: 
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Policz różne wartości za pomocą kilku kliknięć Kutools for Excel

Jeśli musisz często stosować formuły w skoroszycie, zapamiętywanie formuł, gdy będziesz musiał je zastosować następnym razem, może być bolesne. Ale jeśli masz Kutools for Excel, Z siedzibą w Policz komórki z unikalnymi wartościami (uwzględnij pierwszy duplikat) opcja Pomocnik formuł, możesz uzyskać wynik za pomocą zaledwie kilku kliknięć. Zobacz poniżej demo:

  1. Kliknij komórkę, aby wyświetlić wynik;
  2. Włącz tę funkcję, klikając Kutools > Pomocnik formuły > Statystyczny > Policz unikalne komórki z unikalnymi wartościami (uwzględnij pierwszy duplikat);
  3. Wybierz listę danych > OK.
Tips:
  1. Aby zastosować tę funkcję, powinieneś pobierz i zainstaluj po pierwsze.
  2. Połączenia Pomocnik formuł funkcja gromadzi ponad 40 często używanych formuł, takich jak Wyodrębnij unikalne wartości, Wyodrębnij komórki z unikalnymi wartościami (uwzględnij pierwsze duplikaty), Policz liczbę wartości oddzielonych przecinkami, Suma na podstawie tego samego tekstu, i więcej...

Policz różne wartości za pomocą tabeli przestawnej

W programie Excel tabela przestawna może również pomóc w uzyskaniu liczby odrębnych wartości z listy danych, wykonaj następujące czynności:

Krok 1: Utwórz tabelę przestawną

  1. Wybierz listę danych, a następnie kliknij wstawka > Stół obrotowy ze wstążki, zobacz zrzut ekranu:
  2. W wyskoczył Stół obrotowy z okna dialogowego tabeli lub zakresu:
    (1). Wybierz nowy arkusz lub istniejący arkusz, w którym chcesz umieścić tabelę przestawną;
    (2). Następnie sprawdź Dodaj te dane do modelu danych checkbox.
    (3). Następnie kliknij OK przycisk.

Krok 2: Ułóż pole i wybierz opcję Distinct Count

  1.  A Pola tabeli przestawnej zostanie wyświetlony panel, przeciągnij nazwy pole do Wartości obszar, patrz poniżej demo:
  2. Następnie kliknij Liczba imion rozwiń i wybierz Ustawienia pola wartościzobacz zrzut ekranu:
  3. A następnie a Ustawienia pola wartości otworzy się okno dialogowe, wybierz Odrębna liczba z pola listy pod Podsumuj wartość według kartę i kliknij OK przycisk, zobacz zrzut ekranu:

Wynik:

Teraz utworzona tabela przestawna wyświetli wyraźną liczbę listy danych, jak pokazano na poniższym zrzucie ekranu:

Tips:

  1. Jeśli aktualizujesz dane źródłowe, aby uzyskać najnowszą liczbę, wystarczy kliknąć prawym przyciskiem myszy tabelę przestawną i wybrać Odśwież kod opcja.
  2. To Odrębna liczba opcja jest dostępna tylko w programie Excel 2013 i nowszych.

Zliczaj różne wartości w programie Excel 365/2021 za pomocą formuł

W programie Excel 365 lub Excel 2021 możesz użyć nowej funkcji UNIQUE z normalną funkcją ILE.LICZ., aby utworzyć łatwą formułę.

Proszę skopiować lub wpisać poniższą formułę do pustej komórki i nacisnąć Wchodzę klucz do uzyskania wyniku:

=COUNTA(UNIQUE(A2:A12))
Uwagi: W tym wzorze A2: A12 jest listą danych, dla której chcesz policzyć odrębne wartości.

Tips:

  1. Jeśli lista danych zawiera inne typy danych, takie jak tekst, liczby, wartości logiczne, wartości błędów itp., ta formuła zliczy liczbę odrębnych wartości niezależnie od typu danych.
  2. Powyższa formuła zliczy różne wartości, w tym puste komórki, jeśli chcesz wykluczyć puste miejsca, zastosuj poniższą formułę i naciśnij Wchodzę klucz do uzyskania wyniku: 
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

Podobne artykuły:

  • Policz unikalne wartości w tabeli przestawnej
  • Domyślnie, kiedy tworzymy tabelę przestawną na podstawie zakresu danych, który zawiera kilka zduplikowanych wartości, wszystkie rekordy również zostaną policzone, ale czasami chcemy po prostu policzyć unikalne wartości na podstawie jednej kolumny, aby uzyskać właściwą wynik zrzutu ekranu. W tym artykule omówię, jak policzyć unikalne wartości w tabeli przestawnej.
  • Policz unikalne wartości w filtrowanej kolumnie
  • Jeśli masz listę nazw, które zostały wypełnione kilkoma duplikatami w przefiltrowanej kolumnie, a teraz chcesz policzyć liczbę unikalnych nazw tylko z tej przefiltrowanej listy. Czy masz jakieś dobre rozwiązania, aby szybko poradzić sobie z tą pracą w programie Excel?
  • Policz unikalne wartości z wieloma kryteriami
  • Oto szereg danych zawierających kilka nazw, projektów i lokalizacji, a co należy zrobić, to znaleźć nazwy, które pasują do kryteriów, które mam na liście, a następnie policzyć wszystkie pasujące nazwy tylko raz, jak pokazano poniżej. Czy masz jakieś sztuczki, jak rozwiązać tę pracę? W tym artykule przedstawię sztuczki.
  • Połącz unikalne wartości
  • Jeśli mam długą listę wartości, na których znajdują się zduplikowane dane, chcę teraz znaleźć tylko unikatowe wartości, a następnie połączyć je w jedną komórkę. Jak mogę szybko i łatwo poradzić sobie z tym problemem w programie Excel?
Sortuj komentarze według
najstarsze
Najpierw Nowsze
Komentarze (0)
Brak ocen. Oceń jako pierwszy!
Nie ma tu jeszcze żadnych komentarzy

Bądż na bieżąco

Prawa autorskie © 2009 - www.extendoffice.com. | Wszelkie prawa zastrzeżone. Zasilany przez ExtendOffice, | Mapa strony
Microsoft i logo Office są znakami towarowymi lub zastrzeżonymi znakami towarowymi Microsoft Corporation w Stanach Zjednoczonych i / lub innych krajach.
Chronione przez Sectigo SSL