Jak uzyskać listę folderów w Outlooku?

Czasami struktura drzewa wszystkich folderów poczty (w tym utworzonych folderów osobistych) w okienku nawigacji może pomóc użytkownikom programu Outlook podczas ich pracy. Aby szybko wyświetlić listę folderów w całej strukturze drzewa, kod VBA może ci pomóc. Z tego samouczka dowiesz się, jak łatwo uzyskać listę folderów za pomocą kodu VBA.

Pobierz listę folderów w Outlooku z kodem VBA

Pobierz listę folderów w Outlooku z kodem VBA

Aby uzyskać listę folderów w programie Outlook z kodem VBA, wykonaj następujące czynności.

1. wciśnij inny + F11 klawisze na klawiaturze, aby otworzyć Microsoft Visual Basic for Applications okno.

2. Następnie kliknij dwukrotnie plik Project1 > Obiekt programu Microsoft Outlook > Ta sesja programu Outlook otworzyć Project1 - ThisOutlookSession okno. Zobacz zrzut ekranu:

3. Następnie skopiuj i wklej poniższy kod VBA do okna Project1 - ThisOutlookSession.

VBA: pobierz listę folderów w Outlooku

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. wciśnij F5 klawisz na klawiaturze, aby rozpocząć uruchamianie kodu VBA.

5. Teraz a Macro pojawi się okno dialogowe, kliknij run przycisk.

6. Poczekaj na uruchomienie makra. Następnie lista wszystkich folderów poczty e-mail jest natychmiast wyświetlana w utworzonym oknie nowej wiadomości. Możesz go łatwo wydrukować. Zobacz zrzut ekranu:

Uwagi: Ten kod VBA można zastosować w programach Outlook 2007, 2010 i 2013.

---

Kutools dla programu Outlook - wprowadza 100 zaawansowanych funkcji do programu Outlook i znacznie ułatwia pracę!

• Auto CC / BCC według zasad podczas wysyłania wiadomości e-mail; Auto Forward Wiele e-maili na zamówienie; Automatyczna odpowiedź bez serwera Exchange i więcej funkcji automatycznych ...
• Ostrzeżenie BCC - pokaż wiadomość, gdy spróbujesz odpowiedzieć wszystkim jeśli Twój adres e-mail znajduje się na liście BCC; Przypomnij o braku załącznikówi więcej funkcji przypominających ...
• Odpowiedz (wszystkie) ze wszystkimi załącznikami w rozmowie pocztowej; Odpowiedz na wiele e-maili w sekundy; Automatyczne dodawanie powitania kiedy odpowiedz; Dodaj datę do tematu ...
• Narzędzia załączników: Zarządzaj wszystkimi załącznikami we wszystkich wiadomościach e-mail, Automatyczne odłączanie, Kompresuj wszystko, Zmień nazwę wszystkiego, Zapisz wszystko ... Szybki raport, Policz wybrane wiadomości...
• Potężne wiadomości-śmieci na zamówienie; Usuń zduplikowane wiadomości e-mail i kontakty... Umożliwiają inteligentniejsze, szybsze i lepsze działanie w programie Outlook.

Czytaj więcej... Pobierz teraz...