Jak zapisać wiadomość e-mail w formacie obrazu (jpg / tiff) w programie Outlook?

Czy kiedykolwiek próbowałeś zapisać wiadomość e-mail jako obraz, taki jak obraz jpg lub tiff w programie Outlook? Ten artykuł pokaże Ci metodę rozwiązania tego problemu.

Zapisz wiadomość e-mail jako format obrazu z kodem VBA

Zapisz wiadomość e-mail jako format obrazu z kodem VBA

Wykonaj następujące czynności, aby zapisać wiadomość e-mail w formacie obrazu w programie Outlook.

1. Wybierz wiadomość e-mail, którą zapiszesz jako obraz, a następnie naciśnij inny + F11 klawisze jednocześnie, aby otworzyć Microsoft Visual Basic for Applications okno.

2. w Microsoft Visual Basic for Applications kliknij wstawka > UserForm. Zobacz zrzut ekranu:

3. Stwórz Formularz użytkownika jak pokazano na poniższym zrzucie ekranu.

4. Wybierz jpg Opcja i zmień jego nazwę na opbJPG po lewej Właściwości szkło.

5. Powtórz powyższy krok 4, aby zmienić nazwę innego przycisku opcji na opbTIFF. I zmień nazwę OK przycisk polecenia i Anuluj przycisk polecenia jako cdbOK i cdb Anuluj osobno.

Note: Jeśli Właściwości okienko nie jest wyświetlane w Microsoft Visual Basic for Applications kliknij ikonę F4 klawisz, aby wyświetlić okienko.

6. Kliknij dwukrotnie dowolne puste miejsce w formularzu użytkownika, aby otworzyć plik Code okno. Zastąp cały kod następującym skryptem VBA. Następnie zamknij okno Code.

Kod VBA 1: Zapisz wiadomość e-mail jako obraz

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. Wybierz Formularz użytkownika1 i zmień jego nazwę na FrmPicType Właściwości okienko, jak pokazano na zrzucie ekranu poniżej.

8. kliknij wstawka > Moduł, a następnie skopiuj poniższy kod VBA do okna modułu.

Kod VBA 2: Zapisz wiadomość e-mail jako obraz

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. kliknij Tools > Referencje, Sprawdź Biblioteka obiektów programu Microsoft PowerPoint a następnie kliknij OK przycisk. Zobacz zrzut ekranu:

10. wciśnij F5 klucz do uruchomienia kodu. A później Formularz użytkownika1 pojawi się okno dialogowe, wybierz typ obrazu i kliknij OK przycisk. Zobacz zrzut ekranu:

11. w Przeglądaj w poszukiwaniu folderu w oknie dialogowym określ folder, w którym chcesz zapisać obraz, a następnie kliknij przycisk OK przycisk.