Wykonaj poniższe czynności, aby skopiować strukturę folderów programu Outlook do pulpitu lub eksploratora Windows.

1. W okienku nawigacji kliknij, aby podświetlić określony folder, którego strukturę folderów chcesz skopiować, i naciśnij inny + F11 klawisze, aby otworzyć okno Microsoft Visual Basic for Applications.

2. kliknij Tools > Referencje aby otworzyć okno dialogowe Odnośniki. Następnie w oknie dialogowym zaznacz Środowisko wykonawcze skryptów firmy Microsoft Microsoft opcję i kliknij przycisk OK przycisk. Zobacz zrzut ekranu:

3. kliknij wstawka > Modułi skopiuj i wklej poniższy kod VBA do nowego okna modułu.

VBA: Skopiuj strukturę folderów programu Outlook do eksploratora Windows

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. naciśnij F5 lub kliknij run przycisk, aby uruchomić ten VBA.

5. W wyskakującym oknie dialogowym Przeglądaj w poszukiwaniu folderu wybierz określony folder, w którym umieścisz skopiowaną strukturę folderów, i kliknij przycisk OK przycisk. Zobacz zrzut ekranu:

Teraz przejdź do określonego folderu, zobaczysz, że struktura folderów została skopiowana na określony dysk twardy. Zobacz zrzut ekranu:

Note: elementy folderów, takie jak wiadomości e-mail, spotkania, zadania itp. są również kopiowane do odpowiednich folderów na dysku twardym.

Jak skopiować strukturę folderów do nowego pliku danych pst w programie Outlook?