Jak wysłać kalendarz do wielu odbiorców indywidualnie w Outlooku?

Zwykle możesz szybko i łatwo wysłać kalendarz do odbiorcy, korzystając z pliku Kalendarz e-mail funkcja w programie Outlook. Jeśli chcesz wysłać kalendarz załączony jako plik iCalendar do wielu kontaktów indywidualnie, musisz wysłać go pojedynczo. W tym artykule omówię łatwy sposób wysyłania kalendarza do wielu odbiorców indywidualnie w Outlooku.

Wysyłaj kalendarz do wielu odbiorców indywidualnie za pomocą kodu VBA

Wysyłaj kalendarz do wielu odbiorców indywidualnie za pomocą kodu VBA

Aby wysłać kalendarz do wielu odbiorców oddzielnie, poniższy kod VBA może ci pomóc, wykonaj następujące czynności:

1. Przejdź do Kontakt okienku i wybierz kontakty, do których chcesz wysłać kalendarz.

2. Następnie przytrzymaj ALT + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

3. Kliknij wstawka > Moduł, skopiuj i wklej poniższy kod do otwartego pustego modułu, zobacz zrzut ekranu:

Kod VBA: wysyłaj kalendarz do wielu odbiorców indywidualnie ：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. Po wprowadzeniu kodu naciśnij F5 klucz do uruchomienia tego kodu oraz plik Wybierz folder pojawi się okno dialogowe, wybierz kalendarz, który chcesz wysłać, zobacz zrzut ekranu:

5. Kliknij OK, a następnie określ zakres dat, do którego chcesz wysłać kalendarz w następujących polach zachęty, zobacz zrzut ekranu:

6. A następnie kliknij OK, nowe e-maile z załączonym kalendarzem zostały utworzone jak na poniższym zrzucie ekranu, a następnie wystarczy wysłać je jeden po drugim.