Jak automatycznie oznaczać wiadomości e-mail na podstawie określonego załącznika w programie Outlook?

W przypadku otrzymywania niektórych wiadomości e-mail z określonymi, ważnymi załącznikami może być konieczne ich oznaczenie, aby można było je szybko i łatwo znaleźć w celu dalszego przepływu. W tym artykule omówię łatwy sposób automatycznego oznaczania wiadomości e-mail, które są załącznikami o określonych nazwach.

Automatycznie oznaczaj wiadomości e-mail na podstawie określonego załącznika z kodem VBA

---

Automatycznie oznaczaj wiadomości e-mail na podstawie określonego załącznika z kodem VBA

Aby automatycznie oflagować wiadomości e-mail zawierające określony załącznik, zastosuj następujący kod VBA:

1. Uruchom program Outlook, a następnie przytrzymaj ALT + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

2, w Microsoft Visual Basic for Applications kliknij dwukrotnie Ta sesja programu Outlook z Project1 (VbaProject.OTM) okienko, aby otworzyć nowy tryb, a następnie skopiuj i wklej następujący kod do pustego modułu.

Kod VBA: Automatyczne oznaczanie wiadomości e-mail na podstawie określonego załącznika:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Uwagi: W powyższym kodzie możesz zmienić rozszerzenie pliku i nazwę pliku załącznika według swoich potrzeb.

3. Następnie zapisz kod i uruchom ponownie Outlooka, aby kod zaczął obowiązywać, teraz, po otrzymaniu wiadomości e-mail, których nazwy załączników zawierają określony tekst, Outlook automatycznie oznaczy ten e-mail w celu kontynuacji, zobacz zrzut ekranu: