Jak drukować zadania na podstawie kategorii w Outlooku?

Przypuśćmy, że w zadaniach programu Outlook są różne kategorie oznaczone kolorami, a teraz chcesz wydrukować listy zadań na podstawie kategorii na różnych stronach. Jak możesz rozwiązać tę pracę w Outlooku?

Zadania drukowania na podstawie kategorii na różnych stronach ręcznie, jedna po drugiej

Drukuj zadania na podstawie kategorii na różnych stronach z kodem VBA

Zadania drukowania na podstawie kategorii na różnych stronach ręcznie, jedna po drugiej

W programie Outlook możesz ręcznie drukować zadania na podstawie różnych kategorii na różnych stronach, jeden po drugim, wykonaj następujące czynności:

1. Uruchom program Outlook i przejdź do okienka zadań i wybierz folder zadań, który chcesz wydrukować, a następnie naciśnij Ctrl + E aktywować Szukaj pudełko, a następnie pod Szukaj tab, kliknij skategoryzowane ikonę i wybierz jedną kategorię kolorów, którą chcesz wydrukować, zobacz zrzut ekranu:

zadania drukowania doc według kategorii 1

2. Następnie wszystkie zadania z określoną kategorią kolorów są wymienione jednocześnie, patrz zrzut ekranu:

zadania drukowania doc według kategorii 2

3. Następnie kliknij dalej filet > wydrukować tę listę zadań, jak pokazano na poniższym zrzucie ekranu:

zadania drukowania doc według kategorii 3

4. Powtórz powyższe kroki, aby ręcznie wydrukować listy zadań z innymi kategoriami oznaczonymi kolorami.

Drukuj zadania na podstawie kategorii na różnych stronach z kodem VBA

Oto kod VBA, który może pomóc w jednoczesnym wydrukowaniu zadań na podstawie kategorii na różnych stronach, wykonaj następujące czynności:

1. Idź do Zadanie okienku i wybierz folder zadań, który chcesz wydrukować.

2. Następnie przytrzymaj ALT + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

3. A następnie kliknij wstawka > Modułskopiuj i wklej poniższy kod do otwartego pustego modułu:

Kod VBA: Drukuj zadania na podstawie kategorii na różnych stronach:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Następnie kliknij Tools > Referencje Microsoft Visual Basic for Applications okno, w wyskakującym oknie Referencje-projekt 1 okno dialogowe, zaznacz Biblioteka obiektów programu Microsoft Excel i Środowisko wykonawcze skryptów firmy Microsoft Microsoft opcje z Dostępne referencje pole listy, zobacz zrzut ekranu:

zadania drukowania doc według kategorii 4

5. A następnie kliknij OK przycisk, teraz naciśnij F5 Aby uruchomić ten kod, po zakończeniu kodu listy zadań z różnymi kategoriami zostaną wydrukowane na różnych stronach.