Jak normalnie odpowiadać w folderze Wysłane elementy z Outlooka? 

Zwykle po kliknięciu funkcji Odpowiedz w folderze Elementy wysłane w celu wysłania kolejnej dodatkowej wiadomości do osób, które wysłałeś, Twój własny adres e-mail zostanie wyświetlony w polu Do, jak pokazano na zrzucie ekranu. Może to być irytujące, gdy za każdym razem zmieniasz adres. W jaki sposób program Outlook mógł używać adresu pierwotnego odbiorcy, a nie Twojego?

Odpowiadaj normalnie w folderze Elementy wysłane z Outlooka z funkcją Odpowiedz wszystkim

Odpowiadaj normalnie w folderze Elementy wysłane z Outlooka za pomocą kodu VBA

---

Odpowiadaj normalnie w folderze Elementy wysłane z Outlooka z funkcją Odpowiedz wszystkim

W programie Outlook Odpowiedz wszystkim Funkcja może pomóc w rozwiązaniu tego problemu, wykonaj następujące czynności:

Jeśli chcesz ponownie odpowiedzieć na wysłaną wiadomość e-mail w celu wysłania, aby zachować adres pierwotnego odbiorcy, kliknij Odpowiedz wszystkim przycisk, a adres pierwotnego odbiorcy znajduje się w Do pole, jak pokazano na poniższym zrzucie ekranu:

---

Odpowiadaj normalnie w folderze Elementy wysłane z Outlooka za pomocą kodu VBA

Czasami możesz zapomnieć o Odpowiedz wszystkim funkcja podczas odpowiadania na wysłaną wiadomość, więc poniższy kod VBA może pomóc w normalnej odpowiedzi w folderze Elementy wysłane za pomocą funkcji Odpowiedz. Wykonaj następujące czynności:

1. Przytrzymaj ALT + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

2, w Microsoft Visual Basic for Applications kliknij dwukrotnie Ta sesja programu Outlook z Project1 (VbaProject.OTM) okienko, aby otworzyć tryb, a następnie skopiuj i wklej następujący kod do pustego modułu.

Kod VBA: Odpowiedz normalnie w folderze Elementy wysłane z Outlooka:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Następnie zapisz kod i uruchom ponownie program Outlook, aby zastosować efekt kodu, teraz po kliknięciu Odpowiedz aby ponownie wysłać wiadomość e-mail w formacie Elementy wysłane W razie potrzeby w polu Do zostanie wyświetlony adres pierwotnego odbiorcy.