Jak zachować kategorię podczas odpowiadania lub przekazywania wiadomości e-mail w Outlooku? 

Zwykle, gdy odpowiadasz lub przesyłasz dalej wiadomość e-mail, którą skategoryzowałem, kategoria zostanie automatycznie usunięta z wysłanego e-maila. Jeśli chcesz zachować kategorię wychodzących wiadomości e-mail podczas odpowiadania lub przekazywania dalej, w tym artykule przedstawimy metodę radzenia sobie z tym problemem.

Zachowaj kategorię podczas odpowiadania lub przekazywania wiadomości e-mail z kodem VBA

---

Zachowaj kategorię podczas odpowiadania lub przekazywania wiadomości e-mail z kodem VBA

1. Przytrzymaj przycisk ALT + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

2, w Microsoft Visual Basic for Applications kliknij dwukrotnie Ta sesja programu Outlook z Project1 (VbaProject.OTM) okienko, aby otworzyć tryb, a następnie skopiuj i wklej następujący kod do pustego modułu.

Kod VBA: Zachowaj kategorię podczas odpowiadania lub przekazywania wiadomości e-mail:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Następnie zapisz i zamknij to okno kodu, zamknij i uruchom ponownie Outlooka, teraz, gdy odpowiesz lub prześlesz wiadomość e-mail z kategorią, kategoria zostanie zachowana w wiadomości wychodzącej w Elementy wysłanezobacz zrzut ekranu: