Dodaj spację między liczbą a tekstem w komórce w programie Excel
W tym artykule dowiemy się, jak dodać spację między liczbą a tekstem za pomocą formuł w programie Excel.
Przypadek 1: Dodaj spację między liczbą a tekstem - tekst zawsze jest na pierwszym miejscu
Przypadek 2: Dodaj spację między liczbą a tekstem - liczba zawsze jest na pierwszym miejscu
Dodaj spację między liczbą a tekstem - tekst zawsze jest na pierwszym miejscu
Przypuśćmy, że istnieje lista ciągów tekstowych zawierająca liczbę i tekst, gdzie tekst zawsze znajduje się na pierwszym miejscu, jak pokazano na poniższym zrzucie ekranu, możesz dodać spację między liczbą a tekstem za pomocą poniższej formuły.
Formuła ogólna
=TRIM(REPLACE(text_string,MIN(FIND({1,2,3,4,5,6,7,8,9,0},text_string&”1234567890”)),0,” “))
Argumenty
Ciąg tekstowy: Ciąg tekstowy, do którego dodasz spację między tekstem a liczbą. To może być:
- Ciąg tekstowy ujęty w cudzysłów;
- Lub odwołanie do komórki zawierającej ciąg tekstowy.
Jak korzystać z tej formuły?
1. Wybierz pustą komórkę, aby wyświetlić wynik. W tym przypadku wybieram D3.
2. Wprowadź do niego poniższą formułę i naciśnij Wchodzę klucz. Następnie przeciągnij tę komórkę wynikową do końca, aby zastosować formułę do innych komórek.
=TRIM(REPLACE(B3,MIN(FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")),0," "))
Uwagi:
- We wzorze B3 to komórka ciągu tekstowego, do której dodasz spację między tekstem a liczbą;
- Ta formuła może tylko dodać spację przed pierwszą liczbą. Na przykład ta formuła zmieni B34C12G45 na B 34C12G45.
Jak działa ta formuła?
=TRIM(REPLACE(B3,MIN(FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")),0," "))
1. FIND({1,2,3,4,5,6,7,8,9,0},B3&"1234567890")
- B3&"1234567890": zwraca wynik jako: "KutoolsforExcel634211234567890";
- FIND({1,2,3,4,5,6,7,8,9,0}, "KutoolsforExcel634211234567890"): Funkcja ZNAJDŹ znajduje pozycję cyfr „1-0” w KutoolsforExcel634211234567890 i zwraca wynik jako {20,19,17,18,25,16,27,28,29,30}.
Note: Wynik {20,19,17,18,25,16,27,28,29,30} oznacza, że numer 1 jest na 20. pozycji w KutoolsforExcel634211234567890, a numer 2 jest na 19 pozycji w KutoolsforExcel634211234567890…
2. MIN({20,19,17,18,25,16,27,28,29,30})
- Funkcja MIN pobiera minimalną wartość tablicy. Tutaj wynik to 16.
3. REPLACE(KutoolsforExcel63421,16,0," ")
- Tutaj użyj funkcji REPLACE, aby dodać spację do 16 pozycji w KutoolsforExcel63421 i zwrócić wynik jako KutoolsforExcel 63421.
4. =TRIM("KutoolsforExcel 63421")
- Funkcja TRIM usuwa wszystkie spacje z tekstu z wyjątkiem pojedynczych spacji między wyrazami. I nie zachowuje początkowych i końcowych spacji tekstu.
Dodaj spację między liczbą a tekstem - liczba zawsze jest na pierwszym miejscu
Innym przypadkiem, jak pokazano na poniższym zrzucie ekranu, jest lista ciągów tekstowych zawierająca liczbę i tekst, gdzie liczba zawsze jest pierwsza, możesz zastosować poniższą formułę tablicową, aby dodać spację między liczbą a tekstem.
Formuła ogólna
=TRIM(REPLACE(text_string,MAX(IFERROR(FIND({0,1,2,3,4,5,6,7,8,9},text_string,ROW(INDIRECT("1:"&LEN(text_string)))),0))+1,0," ")) + Ctrl + Shift + Wchodzę
Argumenty
Ciąg tekstowy: Ciąg tekstowy, do którego dodasz spację między tekstem a liczbą. To może być:
- Ciąg tekstowy ujęty w cudzysłów;
- Lub odwołanie do komórki zawierającej ciąg tekstowy.
Jak korzystać z tej formuły?
1. Wybierz pustą komórkę (w tym przypadku D3), aby wyświetlić wynik.
2. Wprowadź do niego poniższą formułę, a następnie naciśnij Ctrl + Shift + Wchodzę klucze jednocześnie.
=TRIM(REPLACE(B3,MAX(IFERROR(FIND({0,1,2,3,4,5,6,7,8,9},B3,ROW(INDIRECT("1:"&LEN(B3)))),0))+1,0," "))
3. Wybierz komórkę wynikową, a następnie przeciągnij ją do samego końca, aby zastosować formułę do innych komórek, jak pokazano na poniższym zrzucie ekranu.
Uwagi:
- We wzorze B3 to komórka ciągu tekstowego, do której dodasz spację między tekstem a liczbą;
- Ta formuła tablicowa może dodać spację tylko po ostatniej liczbie. Na przykład ta formuła zmieni 34C12GHH na 34C12 GHH.
Powiązane funkcje
Funkcja Excel TRIM
Funkcja Excel TRIM usuwa wszystkie dodatkowe spacje z ciągu tekstowego i zachowuje tylko pojedyncze spacje między wyrazami.
Funkcja Excel REPLACE
Funkcja Excel REPLACE znajduje i zamienia znaki na podstawie podanej lokalizacji z ciągu tekstowego nowym tekstem.
Funkcja Excel MIN
Funkcja Excel MIN zwraca najmniejszą liczbę ze zbioru wartości.
Funkcja Excel ZNAJDŹ
Funkcja Excel FIND służy do znajdowania ciągu w innym ciągu i zwraca pozycję początkową ciągu w innym.
Funkcja Excel MAX
Funkcja Excel MAX zwraca największą liczbę w zestawie wartości.
Funkcja IFERROR programu Excel
Funkcja JEŻELI BŁĄD służy do zwracania niestandardowego wyniku, gdy formuła oceni błąd, i zwraca normalny wynik, gdy nie wystąpił błąd.
Funkcja Excel WIERSZ
Funkcja Excel WIERSZ zwraca numer wiersza odwołania.
Funkcja Excel POŚR
Funkcja Excel POŚREDNI konwertuje ciąg tekstowy na prawidłowe odwołanie.
Funkcja Excel LEN
Funkcja Excel LEN zwraca liczbę znaków w ciągu tekstowym.
Powiązane wzory
Dodaj przecinek po pierwszym słowie w komórce w programie Excel
Aby dodać przecinek po pierwszym słowie tylko w komórce, formuła w tym samouczku może wyświadczyć ci przysługę.
Dodaj określony znak przed każdym słowem w komórce
W tym artykule wyjaśniono, jak dodać określony znak przed każdym słowem w komórce za pomocą formuły w programie Excel.
Dodaj myślniki do numeru telefonu
W tym artykule wyjaśniono, jak dodawać myślniki do numeru telefonu w określonej komórce za pomocą formuły w programie Excel.
Dodaj przecinek między nazwami
Aby dodać przecinek między nazwami w komórce, formuła w tym samouczku może wyświadczyć ci przysługę.
Najlepsze narzędzia biurowe
Kutools dla programu Excel - pomaga wyróżnić się z tłumu
Kutools dla programu Excel oferuje ponad 300 funkcji, Pewność, że to, czego potrzebujesz, jest w zasięgu jednego kliknięcia...
Karta Office - Włącz czytanie i edycję na kartach w Microsoft Office (w tym Excel)
- Jedna sekunda, aby przełączać się między dziesiątkami otwartych dokumentów!
- Zmniejsz liczbę kliknięć myszą każdego dnia, pożegnaj się z dłonią myszy.
- Zwiększa produktywność o 50% podczas przeglądania i edytowania wielu dokumentów.
- Wprowadza wydajne karty do pakietu Office (w tym programu Excel), podobnie jak przeglądarki Chrome, Edge i Firefox.
