Note: The other languages of the website are Google-translated. Back to English

Oddzielne oktety adresu IP w programie Excel

Czy kiedykolwiek próbowałeś podzielić adresy IP na oddzielne kolumny w arkuszu programu Excel? Może funkcja Text to Column może pomóc w szybkim rozwiązaniu tego zadania, ale w tym artykule omówię niektóre formuły umożliwiające wykonanie tego zadania w programie Excel.


Podziel oktety adresów IP na oddzielne kolumny w programie Excel

Zwykle w programie Excel funkcje LEFT, MID, LEN i FIND mogą pomóc w wyodrębnieniu każdego oktetu z adresu IP do różnych kolumn. Wykonaj następujące czynności:

Podziel pierwszy oktet adresów IP:

Aby wyodrębnić pierwszy oktet adresu IP, zastosuj poniższą formułę do pustej komórki:

=LEFT(A2,FIND(".",A2)-1)

A następnie przeciągnij uchwyt wypełniania w dół do komórek, do których chcesz zastosować tę formułę, a cały pierwszy oktet adresów IP został wyodrębniony, patrz zrzut ekranu:

Wyjaśnienie wzoru:

ZNAJDŹ („.”, A2) -1: Ta funkcja ZNAJDŹ zwraca pozycję pierwszej kropki z komórki A2, odejmuje 1 oznacza wykluczenie samej kropki, otrzymasz wynik 2.

LEFT(A2,FIND(".",A2)-1)=LEFT(A2, 2):Funkcja LEFT służy do wyodrębniania 2 znaków z lewej strony ciągu w komórce A2.


Podziel drugi oktet adresów IP:

Aby uzyskać drugi oktet adresów IP, skopiuj lub wprowadź następującą formułę w pustej komórce:

=MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)

Następnie przeciągnij uchwyt wypełniania w dół do komórek, aby wypełnić tę formułę, a otrzymasz wynik zgodnie z potrzebami, patrz zrzut ekranu:

Wyjaśnienie wzoru:

1. ZNAJDŹ („.”, A2) +1: Ta funkcja ZNAJDŹ zwraca pozycję pierwszej kropki z komórki A2, dodaje 1 środek do ekstrakcji z następnego znaku, otrzymasz wynik o numerze 4. Ta część formuły jest rozpoznawana jako argument nr_początkowy funkcji MID.

2. FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1: Ta część jest rozpoznawana jako argument num_chars w funkcji MID.

  • ZNAJDŹ („.”, A2, ZNAJDŹ („.”, A2) +1) = ZNAJDŹ („.”, A2,4): Ta funkcja ZNAJDŹ zwróci pozycję drugiej kropki. Otrzymasz numer 6.
  • FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1=6-3-1: Odejmij pozycję pierwszej kropki od pozycji drugiej kropki, a następnie odejmij 1 od średniej wynikowej, aby usunąć wiodącą kropkę. Wynik to 2.

3. MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)=MID(A2, 4, 2): Wreszcie ta funkcja MID służy do wyodrębniania 2 znaków, które zaczynają się od czwartego znaku z komórki A2.


Podziel trzeci oktet adresów IP:

Aby wyodrębnić trzeci oktet adresów IP, funkcje MID i FIND również mogą wyświadczyć ci przysługę, wprowadź lub skopiuj następującą formułę do pustej komórki:

=MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))

Następnie przeciągnij uchwyt wypełniania w dół, aby uzyskać wyniki zgodnie z potrzebami, a tylko trzeci oktet adresów IP został podzielony, patrz zrzut ekranu:

Wyjaśnienie wzoru:

1. FIND(".",A2,FIND(".",A2)+1)+1: Ta zagnieżdżona funkcja ZNAJDŹ służy do określenia pozycji drugiej kropki w komórce A2, dodając 1 środek do ekstrakcji z następnego znaku, a otrzymasz liczbę 7. Ta część jest rozpoznawana jako argument nr_początkowy funkcji MID.

2. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1): Ta część formuły jest rozpoznawana jako argument num_chars funkcji MID.

  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=FIND(".",A2, 7): Ta zagnieżdżona funkcja ZNAJDŹ służy do określenia pozycji trzeciej kropki w komórce A2, zwraca liczbę 8.
  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1)=8-7: Odejmij pozycję drugiej kropki od pozycji trzeciej kropki, a wynik to 1.

3.MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 7, 1): Ta funkcja MID otrzyma 1 znak, który zaczyna się od siódmego znaku z komórki A2.


Podziel czwarty oktet adresów IP:

Poniższa formuła może pomóc wyodrębnić ostatni oktet adresu IP, skopiuj lub wprowadź formułę do pustej komórki:

=MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))

A następnie przeciągnij uchwyt wypełniania, aby wypełnić tę formułę do innych potrzebnych komórek, otrzymasz wynik jak na poniższym zrzucie ekranu:

Wyjaśnienie wzoru:

1. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1: Ta zagnieżdżona funkcja ZNAJDŹ służy do określenia pozycji trzeciej kropki w komórce A2, dodając 1 środek do ekstrakcji z następnego znaku, a otrzymasz liczbę 9. Ta część jest rozpoznawana jako argument nr_początkowy funkcji MID.

2. LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1):

  • DŁ (A2): Funkcja DŁ zwraca całkowitą liczbę znaków w komórce A2. Otrzyma numer 11.
  • LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=11-8: Całkowita długość komórki A2 odejmuje pozycję trzeciej kropki, aby uzyskać liczbę pozostałych znaków. To da numer 3.

3. MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 9, 3): W końcu ta funkcja MID otrzyma 3 znaki, które zaczynają się od dziewiątego znaku z komórki A2.


Używane funkcje względne:

  • LEFT:
  • Funkcja LEFT wyodrębnia podaną liczbę znaków z lewej strony podanego ciągu.
  • MID:
  • Funkcja MID służy do wyszukiwania i zwracania określonej liczby znaków ze środka danego ciągu tekstowego.
  • FIND:
  • Funkcja ZNAJDŹ służy do znajdowania ciągu w innym ciągu i zwraca pozycję początkową ciągu w innym.
  • LEN:
  • Funkcja DŁ zwraca liczbę znaków w ciągu tekstowym.

Więcej artykułów:

  • Podziel tekst i liczby w komórce w programie Excel
  • Przypuśćmy, że dane komórki są pomieszane z tekstem i liczbami, jak podzielić je na oddzielne komórki w kolumnach? Ten samouczek pokaże ci szczegółowe kroki, aby rozwiązać problem za pomocą formuł.

Najlepsze narzędzia biurowe

Kutools dla programu Excel - pomaga wyróżnić się z tłumu

Chcesz szybko i perfekcyjnie zakończyć swoją codzienną pracę? Kutools dla programu Excel oferuje 300 zaawansowanych zaawansowanych funkcji (Łącz skoroszyty, sumuj według koloru, dziel zawartość komórek, konwertuj daty itd.) i oszczędzaj 80% czasu.

  • Zaprojektowany dla 1500 scenariuszy pracy, pomaga rozwiązać 80% problemów z Excelem.
  • Zmniejsz tysiące kliknięć klawiatury i myszy każdego dnia, odciąż zmęczone oczy i dłonie.
  • Zostań ekspertem Excela w 3 minuty. Nie musisz już pamiętać żadnych bolesnych formuł i kodów VBA.
  • 30-dniowy nieograniczony bezpłatny okres próbny. 60-dniowa gwarancja zwrotu pieniędzy. Bezpłatna aktualizacja i wsparcie przez 2 lata.
Wstążka programu Excel (z zainstalowanym Kutools dla programu Excel)

Karta Office - Włącz czytanie i edycję na kartach w Microsoft Office (w tym Excel)

  • Jedna sekunda, aby przełączać się między dziesiątkami otwartych dokumentów!
  • Zmniejsz liczbę kliknięć myszą każdego dnia, pożegnaj się z dłonią myszy.
  • Zwiększa produktywność o 50% podczas przeglądania i edytowania wielu dokumentów.
  • Wprowadza wydajne zakładki do pakietu Office (w tym Excel), podobnie jak Chrome, Firefox i nowy Internet Explorer.
Zrzut ekranu programu Excel (z zainstalowaną kartą Office)
Sortuj komentarze według
Komentarze (1)
Znamionowy 5 z 5 · 1 oceny
Ten komentarz został zminimalizowany przez moderatora na stronie
To zadziałało pięknie, dziękuję za tę informację!!
Znamionowy 5 z 5
Nie ma tu jeszcze żadnych komentarzy
Zostaw swój komentarz
Publikowanie jako gość
×
Oceń ten post:
0   Postacie
Sugerowane lokalizacje

Bądż na bieżąco

Prawa autorskie © 2009 - www.extendoffice.com. | Wszelkie prawa zastrzeżone. Zasilany przez ExtendOffice, | Mapa strony
Microsoft i logo Office są znakami towarowymi lub zastrzeżonymi znakami towarowymi Microsoft Corporation w Stanach Zjednoczonych i / lub innych krajach.
Chronione przez Sectigo SSL