Wyodrębnij nazwę pliku ze ścieżki w programie Excel
W tym samouczku wyjaśniono, jak zastosować formuły w celu wyodrębnienia nazwy pliku z rozszerzeniem lub bez ze ścieżki pliku w określonej komórce w programie Excel.
Wyodrębnij nazwę pliku z rozszerzeniem ze ścieżki
Wyodrębnij nazwę pliku bez rozszerzenia ze ścieżki
Wyodrębnij nazwę pliku z rozszerzeniem ze ścieżki
Jak pokazano na poniższym zrzucie ekranu, znajduje się lista zawierająca różne ścieżki plików i chcesz wyodrębnić z nich tylko nazwy plików z rozszerzeniami, poniższa formuła pomoże ci rozwiązać problem.
Formuła ogólna
=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))
Argumenty
A1: Reprezentuje komórkę zawierającą ścieżkę do pliku, z którego wyodrębnisz nazwę pliku.
Jak korzystać z tej formuły?
1. Wybierz pustą komórkę, aby wyprowadzić nazwę pliku. W tym przypadku wybieram komórkę D3.
2. Wprowadź do niego poniższą formułę i naciśnij Wchodzę klucz. Wybierz komórkę wynikową, a następnie przeciągnij jej uchwyt wypełnienia do końca, aby zastosować go do innych komórek.
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
Teraz wszystkie nazwy plików z rozszerzeniami w określonych ścieżkach plików są wyodrębniane, jak pokazano na powyższym zrzucie ekranu.
Uwagi:
- W tej formule B3 to komórka zawierająca ścieżkę pliku. Zmień to, jak potrzebujesz.
- Jeśli nazwa pliku nie ma więcej niż 99 znaków, do rozwiązania problemu można również użyć poniższej, krótszej formuły. Zobacz poniższy zrzut ekranu.
=TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
Jak działa ta formuła?
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))
- LEN(B3): Funkcja LEN oblicza całkowitą długość w „D: \\ files \ work \ Q1 \ Jan \ text.txt” i zwraca wynik jako 30;
- LEN(SUBSTITUTE(B3,"\","")): Funkcja SUBSTITUTE zastępuje znak „\” niczym. Wynik to „D: filesworkQ1Jantext.txt”. Następnie funkcja LEN oblicza całkowitą długość „D: filesworkQ1Jantext.txt” i uzyskuje wynik 24;
- SUBSTITUTE(B3,"\","*",30-24): Funkcja SUBSTITUTE zastępuje trzeci znak (30-24 = 6) „\” w „D: \\ files \ work \ Q1 \ Jan \ text.txt” pojedynczym znakiem „*”. Tutaj wynik to „D: \\ files \ work \ Q1 \ Jan * text.txt”;
- FIND("*","D:\\files\work\Q1\Jan*text.txt"): Funkcja ZNAJDŹ lokalizuje pozycję znaku „*” w „D: \\ files \ work \ Q1 \ Jan * text.txt” i na koniec zwraca 22. Tutaj oznacza, że znak „*” jest na 22 pozycji w „ D: \\ files \ work \ Q1 \ Jan * text.txt ”.
2. =MID(B3,22+1,LEN(B3))
- Jak pokazano powyżej, LEN (B3) zwraca wynik jako 30, tutaj funkcja MID może być pokazana jako = MID ("D: \\ files \ work \ Q1 \ Jan \ text.txt", 23,30). Oznacza to, że funkcja MID wyodrębnia 30 znaków z ciągu „D: \\ files \ work \ Q1 \ Jan \ text.txt”, zaczynając od 23. znaku. Tutaj wynik to text.txt.
Wyodrębnij nazwę pliku bez rozszerzenia ze ścieżki
Inną okolicznością może być po prostu wyodrębnienie nazwy pliku bez rozszerzenia ze ścieżki, jak pokazano na poniższym zrzucie ekranu. W tej sekcji znajdziesz długą formułę, która pomoże Ci go obniżyć.
Formuła ogólna
=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")
Argumenty
A1: Reprezentuje komórkę zawierającą ścieżkę do pliku, z którego wyodrębnisz nazwę pliku.
CHAR (1): CHAR (1) tutaj można zastąpić dowolnym numerem CHAR, jeśli potrzebujesz. Lub można go zastąpić określonym symbolem ujętym w cudzysłów, takim jak „*”.
Jak korzystać z tej formuły?
1. Wybierz pustą komórkę, aby wyprowadzić nazwę pliku bez rozszerzenia.
2. Wprowadź do niego poniższą formułę i naciśnij Wchodzę klucz. Wybierz komórkę wynikową, a następnie przeciągnij jej uchwyt wypełnienia do końca, aby zastosować go do innych komórek.
=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")
Note: W tej formule B3 to komórka zawierająca ścieżkę pliku. Zmień to, jak potrzebujesz.
Powiązane funkcje
Funkcja Excel MID
Funkcja Excel MID służy do wyszukiwania i zwracania określonej liczby znaków ze środka podanego ciągu tekstowego.
Funkcja Excel ZNAJDŹ
Funkcja Excel FIND służy do znajdowania ciągu w innym ciągu i zwraca pozycję początkową ciągu w innym.
Funkcja Excel SUBSTITUTE
Funkcja SUBSTITUTE programu Excel zastępuje tekst lub znaki w ciągu tekstowym innym tekstem lub znakami.
Funkcja Excel LEN
Funkcja Excel LEN zwraca liczbę znaków w ciągu tekstowym.
Funkcja IFERROR programu Excel
Funkcja JEŻELI BŁĄD służy do zwracania niestandardowego wyniku, gdy formuła oceni błąd, i zwraca normalny wynik, gdy nie wystąpił błąd.
Powiązane wzory
Wyodrębnij wiele linii z komórki
Jeśli masz listę ciągów tekstowych, które są oddzielone znakami końca linii (co dzieje się po naciśnięciu klawiszy Alt + Enter podczas wprowadzania tekstu) i chcesz wyodrębnić te wiersze tekstu do wielu komórek, formuła w tym samouczku pomoże przysługa.
Wyodrębnij ostatni wiersz tekstu z komórki wieloliniowej
Aby wyodrębnić ostatni wiersz tekstu z ciągu tekstowego oddzielonego znakami końca wiersza, formuła w tym samouczku może pomóc w rozwiązaniu tego zadania w programie Excel.
Wyodrębnij n-te słowo z ciągu tekstowego w programie Excel
W tym artykule wyjaśniono, jak za pomocą formuły wyodrębnić określone n-te słowo z ciągu tekstowego w komórce w programie Excel.
Wyodrębnij ostatnie dwa słowa z komórki w programie Excel
W tym samouczku wyjaśniono, jak używać formuły do wyodrębniania dwóch ostatnich słów z komórki w programie Excel.
Wyodrębnij słowo zaczynające się od określonej postaci w programie Excel
Ten samouczek zawiera formułę ze szczegółowymi krokami, które pomogą Ci wyodrębnić słowo, które zaczyna się od określonego znaku z ciągu tekstowego w komórce w programie Excel.
Wyodrębnij wszystkie słowa oprócz pierwszego lub ostatniego
W tym samouczku nauczysz się, jak używać formuł do wyodrębniania wszystkich słów z komórki z wyjątkiem pierwszego lub ostatniego w programie Excel.
Najlepsze narzędzia biurowe
Kutools dla programu Excel - pomaga wyróżnić się z tłumu
Kutools dla programu Excel oferuje ponad 300 funkcji, Pewność, że to, czego potrzebujesz, jest w zasięgu jednego kliknięcia...
Karta Office - Włącz czytanie i edycję na kartach w Microsoft Office (w tym Excel)
- Jedna sekunda, aby przełączać się między dziesiątkami otwartych dokumentów!
- Zmniejsz liczbę kliknięć myszą każdego dnia, pożegnaj się z dłonią myszy.
- Zwiększa produktywność o 50% podczas przeglądania i edytowania wielu dokumentów.
- Wprowadza wydajne karty do pakietu Office (w tym programu Excel), podobnie jak przeglądarki Chrome, Edge i Firefox.
