Jak automatycznie przenosić różne typy usuniętych elementów do różnych folderów w Outlooku?

W programie Outlook wszystkie rodzaje usuniętych elementów (poczty, zadania, kontakty itp.) zostaną przeniesione do folderu Elementy usunięte. Jeśli chcesz przenieść elementy do różnych folderów na podstawie typu elementu w folderze Elementy usunięte, jak pokazano na poniższym zrzucie ekranu, jak możesz to zrobić w Outlooku?

Przenieś automatycznie różne typy usuniętych elementów do różnych folderów za pomocą kodu VBA

Poniższy kod VBA może pomóc automatycznie przenieść usunięte elementy do różnych folderów, wykonaj następujące czynności:

1. Uruchom Outlooka, a następnie przytrzymaj ALT + F11 klawisze, aby otworzyć Microsoft Visual Basic for Applications okno.

2. Następnie kliknij dwukrotnie Ta sesja programu Outlook z Projekt-Projekt1 okienko, a następnie skopiuj i wklej poniższy kod do pustego okna kodu:

Kod VBA: automatycznie przenieś różne typy usuniętych elementów do różnych folderów

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Następnie zapisz ten kod i uruchom ponownie program Outlook, aby aktywować ten kod.

4. Od teraz, gdy usuniesz element, zostanie on przeniesiony do odpowiedniego folderu pod Usunięte przedmioty folder automatycznie.

5. Aby wyświetlić wynik, kliknij na dole panelu folderów, a następnie kliknij Teczki aby rozwinąć wszystkie foldery w panelu, zobacz zrzuty ekranu: