Przejdź do głównej zawartości

przewyższać SUMPRODUCT funkcjonować

W programie Excel funkcja SUMPRODUCT może służyć do mnożenia dwóch lub więcej kolumn lub tablic, a następnie do uzyskania sumy iloczynów. W rzeczywistości SUMPRODUCT jest użyteczną funkcją, która może pomóc zliczać lub sumować wartości komórek przy użyciu wielu kryteriów, takich jak funkcja LICZ.WARUNKI lub SUMA.WARUNKÓW. W tym artykule przedstawimy składnię funkcji i kilka przykładów dla tej funkcji SUMPRODUCT.


 Składnia:

Składnia funkcji SUMPRODUCT w programie Excel jest następująca:

=SUMPRODUCT (array1, [array2], ...)

 argumenty:

  • array1: Wymagany. Pierwsza tablica lub pierwszy zakres komórek, które chcesz pomnożyć, a następnie dodać.
  • array2: Opcjonalny. Druga tablica lub zakres komórek, które chcesz pomnożyć, a następnie dodać.

Uwagi:

  • 1. Jeśli zakres zawiera wartości nienumeryczne, SUMPRODUCT traktuje je jako zera.
  • 2. Jeśli tablice lub zakresy mają różną liczbę wierszy i kolumn, funkcja SUMPRODUCT zwróci #ARG! błąd.
  • 3. Jeśli tablice zawierają testy logiczne, utworzą wartości TRUE i FALSE. W większości przypadków należałoby przekonwertować je na 1 i 0 za pomocą podwójnego operatora jednoargumentowego (-).
  • 4. Funkcja SUMPRODUCT może obsłużyć do 255 argumentów w programie Excel 2007 i nowszych wersjach i tylko 30 argumentów we wcześniejszych wersjach programu Excel.
  • 5. SUMPRODUCT nie obsługuje symboli wieloznacznych.

 Powrót:

Zwróć wynik pomnożonych i zsumowanych tablic.


 Przykłady:

Przykład 1: Podstawowe użycie funkcji SUMPRODUCT

Podstawowym zastosowaniem SUMPRODUCT jest pomnożenie dwóch kolumn, a następnie dodanie ich, na przykład masz następujące dane zrzutu ekranu, teraz chcesz pomnożyć zamówienie i cenę jednostkową, a następnie zsumować wszystkie wyniki mnożenia razem, aby uzyskać cena całkowita.

Aby poradzić sobie z tym zadaniem, zastosuj poniższą formułę:

=SUMPRODUCT(B2:B7,C2:C7)

Wyjaśnienie: Ta formuła SUMPRODUCT(B2:B7,C2:C7) = B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7.

A następnie naciśnij Wchodzę klucz, komórki w kolumnie B są mnożone przez odpowiadające im komórki w tym samym wierszu kolumny C, a wyniki są sumowane. Zobacz zrzut ekranu:


Przykład 2: Suma komórek z wieloma kryteriami z funkcją SUMPRODUCT

Z wyjątkiem funkcji SUMA.WARUNKÓW, która służy do sumowania wartości komórek na podstawie wielu warunków, funkcja SUMA.WARUNKÓW może również szybko i łatwo rozwiązać to zadanie.


Przypadek 1: Sumuj wartości komórek, jeśli zawiera określony tekst w innej kolumnie

Przypuśćmy, że masz tabelę danych, jak pokazano na poniższym zrzucie ekranu, teraz chcesz obliczyć całkowitą cenę produktu KTE, a imię to David, jak możesz to zrobić, używając formuły SUMPRODUCT w programie Excel?

1. Wprowadź lub skopiuj jedną z poniższych formuł do pustej komórki:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12="David"), D2:D12)
=SUMPRODUCT((A2:A12="KTE")*(B2:B12="David")*D2:D12)
  • Tips: W powyższym wzorze:
  • A2: A12 = „KTE”: to pierwszy zakres kryteriów i kryteria, na podstawie których chcesz zsumować.
  • B2: B12 = „Dawid”: to drugie kryterium_zakres i kryteria, na podstawie których chcesz zsumować.
  • D2: D12: to zakres sumy, w którym chcesz zsumować wartości komórek.

2. Następnie naciśnij Wchodzę klucz, aby uzyskać pożądany wynik:


Przypadek2: Suma komórek z wieloma kryteriami z logiką OR

Aby zsumować komórki na podstawie wielu kryteriów z logiką LUB, należy użyć symbolu plusa (+), aby połączyć wiele warunków razem w funkcji SUMPRODUCT.

Na przykład chcę zsumować całkowitą cenę produktu KTE i KTO w kolumnie A, jak pokazano na poniższym zrzucie ekranu:

Zastosuj następującą formułę do pustej komórki:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"), C2:C12)

A następnie naciśnij Wchodzę klucz, obliczono całkowitą cenę produktu KTE i KTO, patrz zrzut ekranu:


Przypadek3: sumuj komórki z wieloma kryteriami z logiką OR i AND

W niektórych sytuacjach może być konieczne jednoczesne zsumowanie komórek z logiką OR i AND. Funkcja SUMPRODUCE również może z łatwością rozwiązać to zadanie.

Gwiazdka (*) jest używany jako operator AND.

Symbol plusa (+) jest używany jako operator OR.

Zobaczmy przykład, aby zsumować cenę całkowitą, który produkt to KTE i KTO, gdy sprzedaż jest większa niż 200.

Powinieneś skopiować lub wprowadzić poniższą formułę:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO"))*C2:C12)

Następnie naciśnij Wchodzę klucz, aby uzyskać pożądany wynik:


Przykład 3: Policz komórki z wieloma kryteriami za pomocą funkcji SUMPRODUCT

Ogólnie rzecz biorąc, ta funkcja SUMPRODUCT może również pomóc nam policzyć komórki z wieloma kryteriami w programie Excel. Tak samo jak wartości sum, wystarczy usunąć argument sum_range z formuły.


Przypadek1: Policz komórki z wieloma kryteriami za pomocą logiki AND

Tutaj chcę policzyć komórki, w których produkt to KTE, a sprzedaż jest większa niż 200. Dlatego użyj jednej z poniższych formuł:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12>200))
=SUMPRODUCT((A2:A12="KTE")*(B2:B12>200))
  • Tips: W powyższym wzorze:
  • A2: A12 = „KTE”: to pierwszy zakres kryteriów i kryteria, na podstawie których chcesz liczyć.
  • B2: B12> 200: to drugie kryterium_zakres i kryteria, na podstawie których chcesz liczyć.

A następnie naciśnij Wchodzę klucz, aby uzyskać numer wyniku:


Przypadek2: Policz komórki z wieloma kryteriami z logiką OR

Aby policzyć liczbę produktów KTE i KTO w kolumnie A, zastosuj następujący wzór:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"))

A następnie naciśnij Wchodzę klucz, aby uzyskać numer produktu KTE i KTO. Zobacz zrzut ekranu:


Przypadek3: Policz komórki z wieloma kryteriami z logiką OR i AND

Aby policzyć ilość produktów KTE i KTO, których sprzedaż jest większa niż 200, należy zastosować następujący wzór:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO")))

Następnie wciśnij Wchodzę klucz do uzyskania wymaganej liczby wyników:


Przykład 4: Oblicz średnią ważoną za pomocą funkcji SUMPRODUCT

Zwykle możemy szybko i łatwo obliczyć średni zakres komórek. Jeśli jednak chcesz obliczyć średnią z listy wartości o różnych poziomach trafności, oznacza to obliczenie średniej ważonej. W programie Excel nie ma bezpośredniej funkcji. Ale funkcja SUMPRODUCT może pomóc sobie z tym poradzić.

Na przykład mam tabelę statystyk ocen dla ucznia, każde zadanie ma inną wagę, jak pokazano poniżej.

Aby obliczyć średnią ważoną, użyj następującego wzoru:

=SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6)

Wyjaśnienie: Ta formuła: SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6) = (B2*C2+B3*C3+B4*C4+B5*C5+B6*C6)/(C2+C3+C4+C5+C6)

A następnie naciśnij Wchodzę klucz, średnia ważona została obliczona od razu, patrz zrzut ekranu:


 Więcej artykułów z funkcją SUMPRODUCT:

  • Oblicz średnią ważoną w programie Excel
  • Na przykład masz listę zakupów z cenami, wagami i kwotami. Możesz łatwo obliczyć średnią cenę za pomocą funkcji ŚREDNIA w programie Excel. Ale co, jeśli średnia ważona cena? W tym artykule przedstawię metodę obliczania średniej ważonej, a także metodę obliczania średniej ważonej przy spełnieniu określonych kryteriów w Excelu.

Najlepsze narzędzia biurowe

Kutools dla programu Excel - pomaga wyróżnić się z tłumu

🤖 Pomocnik AI Kutools: Zrewolucjonizuj analizę danych w oparciu o: Inteligentne wykonanie   |  Wygeneruj kod  |  Twórz niestandardowe formuły  |  Analizuj dane i generuj wykresy  |  Wywołaj funkcje Kutools...
Popularne funkcje: Znajdź, wyróżnij lub zidentyfikuj duplikaty  |  Usuń puste wiersze  |  Łącz kolumny lub komórki bez utraty danych  |  Okrągły bez wzoru ...
Super VLookup: Wiele kryteriów  |  Wiele wartości  |  W wielu arkuszach  |  Wyszukiwanie rozmyte...
Adw. Lista rozwijana: Łatwa lista rozwijana  |  Zależna lista rozwijana  |  Lista rozwijana wielokrotnego wyboru...
Menedżer kolumn: Dodaj określoną liczbę kolumn  |  Przesuń kolumny  |  Przełącz stan widoczności ukrytych kolumn  Porównaj kolumny z Wybierz Te same i różne komórki ...
Polecane funkcje: Fokus siatki  |  Widok projektu  |  Duży pasek formuły  |  Menedżer skoroszytów i arkuszy | Biblioteka zasobów (Automatyczny tekst)  |  Selektor dat  |  Połącz arkusze  |  Szyfruj/odszyfruj komórki  |  Wysyłaj e-maile według listy  |  Super filtr  |  Specjalny filtr (filtruj pogrubienie/kursywa/przekreślenie...) ...
15 najlepszych zestawów narzędzi12 Tekst Tools (Dodaj tekst, Usuń znaki ...)  |  50 + Wykres rodzaje (Wykres Gantta ...)  |  40+ Praktyczne Wzory (Oblicz wiek na podstawie urodzin ...)  |  19 Wprowadzenie Tools (Wstaw kod QR, Wstaw obraz ze ścieżki ...)  |  12 Konwersja Tools (Liczby na słowa, Przeliczanie walut ...)  |  7 Połącz i podziel Tools (Zaawansowane wiersze łączenia, Podziel komórki Excela ...)  |  ... i więcej

Kutools dla programu Excel oferuje ponad 300 funkcji, Pewność, że to, czego potrzebujesz, jest w zasięgu jednego kliknięcia...

Opis


Karta Office - Włącz czytanie i edycję na kartach w Microsoft Office (w tym Excel)

  • Jedna sekunda, aby przełączać się między dziesiątkami otwartych dokumentów!
  • Zmniejsz liczbę kliknięć myszą każdego dnia, pożegnaj się z dłonią myszy.
  • Zwiększa produktywność o 50% podczas przeglądania i edytowania wielu dokumentów.
  • Wprowadza wydajne karty do pakietu Office (w tym programu Excel), podobnie jak przeglądarki Chrome, Edge i Firefox.
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Posting as Guest
×
Rate this post:
0   Characters
Suggested Locations